Автоматическое сохранение вложений из почты с помощью AppleScript
Скрипт работает в связке с «Правилами» в почте, что позволяет легко отфильтровать вложения, которые нужно сохранить. Скрипт просто добавляет метку с именем и сохраняет их в указанную папку.
Откройте редактор Script Editor:
/Программы/Утилиты/Script Editor
Скопируйте и вставьте в редактор следующий код:
on perform_mail_action(ruleData)
-- Папка для сохранения вложений (должна уже быть)
set attachmentsFolder to ((path to home folder as text) & "Documents:Attachments") as text
-- Сохранить в подпапке, названной на основе имени правила в почте
set subFolder to name of |Rule| of ruleData as text
tell application "Finder"
if not (exists folder subFolder of folder attachmentsFolder) then
make new folder at attachmentsFolder with properties {name:subFolder}
end if
end tell
-- Получить входящие сообщения, которые соответствуют правилу
tell application "Mail"
set selectedMessages to |SelectedMessages| of ruleData
repeat with theMessage in selectedMessages
-- Получить дату отправки сообщения
set {year:y, month:m, day:d, hours:h, minutes:min} to theMessage's date sent
set timeStamp to ("" & y & "-" & my pad(m as integer) & "-" & my pad(d) & "-" & my pad(h) & "-" & my pad(min))
-- Сохранить вложения
repeat with theAttachment in theMessage's mail attachments
set originalName to name of theAttachment
set savePath to attachmentsFolder & ":" & subFolder & ":" & timeStamp & " " & originalName
try
save theAttachment in savePath
end try
end repeat
end repeat
end tell
end perform_mail_action
on pad(n)
return text -2 thru -1 of ("00" & n)
end pad
Далее нажмите кнопку компиляции и проверить нет ли ошибок.
В третьей строке указывается папка, куда вложения будут сохраняться (в данном случае в папку «Attachments», расположенную в Documents).
Теперь надо настроить правила в почте. Для этого перейдите в настройки почты и нажмите на вкладку Фильтры [Rules], после чего нажмите кнопку Добавить [Add Rule] и введите имя для нового правила. Это имя будет использоваться для создания подпапки в «Attachments», то есть можно создать несколько правил для фильтрации различных типов вложений.
Далее задайте условия, при выполнении которых будет запускаться скрипт. Используя фильтр «Тип вложения», можно сохранять вложения определенного расширения, например, только презентации PowerPoint или изображения.
Теперь выберите “Запустить скрипт” [Run AppleScript] из выпадающего списка в пункте “Выполнить следующие действия” [Perform the following actions:] и укажите путь к сохраненному скрипту.
