@macmaniac_ru

Автоматическое сохранение вложений из почты с помощью AppleScript

Скрипт работает в связке с «Правилами» в почте, что позволяет легко отфильтровать вложения, которые нужно сохранить. Скрипт просто добавляет метку с именем и сохраняет их в указанную папку.

Для этого надо открыть редактор AppleScript из Программы/Утилиты [Applications/Utilities].

Скопировать и вставить следующее:

on perform_mail_action(ruleData)
-- Папка для сохранения вложений (должна уже быть)
set attachmentsFolder to ((path to home folder as text) & "Documents:Attachments") as text
-- Сохранить в подпапке, названной на основе имени правила в почте
set subFolder to name of |Rule| of ruleData as text
tell application "Finder"
if not (exists folder subFolder of folder attachmentsFolder) then
make new folder at attachmentsFolder with properties {name:subFolder}
end if
end tell
-- Получить входящие сообщения, которые соответствуют правилу
tell application "Mail"
set selectedMessages to |SelectedMessages| of ruleData
repeat with theMessage in selectedMessages
-- Получить дату отправки сообщения
set {year:y, month:m, day:d, hours:h, minutes:min} to theMessage's date sent
set timeStamp to ("" & y & "-" & my pad(m as integer) & "-" & my pad(d) & "-" & my pad(h) & "-" & my pad(min))
-- Сохранить вложения
repeat with theAttachment in theMessage's mail attachments
set originalName to name of theAttachment
set savePath to attachmentsFolder & ":" & subFolder & ":" & timeStamp & " " & originalName
try
save theAttachment in savePath
end try
end repeat
end repeat
end tell
end perform_mail_action
on pad(n)
return text -2 thru -1 of ("00" & n)
end pad

Далее нажать кнопку компиляции и проверить нет ли ошибок.

В третьей строке указывается папка, куда вложения будут сохраняться (в данном случае в папку «Attachments», расположенную в Documents).

Теперь надо настроить правила в почте. Для этого следует перейти в настройки почты и нажать на вкладку Фильтры [Rules], после чего нажать кнопку Добавить [Add Rule] и присвоить имя новому правилу. Это имя будет использоваться для создания подпапки в «Attachments», то есть можно создать несколько правил для фильтрации различных типов вложений.

Далее необходимо задать условия, при выполнении которых будет запускаться скрипт. Используя фильтр «Тип вложения», можно сохранять вложения определенного расширения, например, только презентации PowerPoint или изображения.

Теперь надо выбрать «Запустить скрипт» [Run AppleScript] из выпадающего списка в пункте «Выполнить следующие действия» [Perform the following actions:] и указать путь к сохраненному скрипту.